One Function to Rule All URLs

(This is a cross-post from my personal blog…)

I was recently working on implementing Twitter integration features to the DotNetNuke Blog Module (I’ll write up the details about these features in another blog entry) when I quickly ran into the requirement of having to shorten the blog entries’ URLs. As you may or may not know, Twitter requires that messages be less than 140 characters in length and when you include a link and a title, among other things, character real estate  quickly becomes precious.

As it turns out, there are several services out there that provide just this service, for example TinyURL.com. Almost all URL shrinking services also provide APIs that enable developers to gain access to the URL shrinking function.

As I began researching the multitude of URL shrinking services in order to select my provider of choice I found that they all pretty much exposed the shrinking method the same way. Well, since that was the case, then why restrict myself to just one service? Why not just write one function to rule them all?

With that thought in mind, I built this function, that while it does not include ALL URL shrinking services (I don’t think I could possibly find all of them – you can help though, read through the end) it does include 3 of the most popular ones out there: TinyURL, Is.gd, and zi.ma; here it is:

        Public Shared Function ShrinkURL(ByVal Url As String, ByVal Provider As String) As String
            Try
                'TinyUrl's minimum url lenght is 25
                'We should shrink our url only is legth is more that 25 charachters
                If Url.Length <= 25 Then
                    Return Url
                End If

                Dim strServiceUrl As String = String.Empty
                Select Case Provider.ToLower
                    Case "tinyurl"
                        strServiceUrl = "http://tinyurl.com/api-create.php?url="
                    Case "isgd"
                        strServiceUrl = "http://is.gd/api.php?longurl="
                    Case "zima"
                        strServiceUrl = "http://zi.ma/?module=ShortURL&file=Add&mode=API&url="
                    Case Else
                        strServiceUrl = "http://tinyurl.com/api-create.php?url="
                End Select

                If Not Url.ToLower().StartsWith("http") AndAlso Not Url.ToLower().StartsWith("ftp") Then
                    Url = "http://" + Url
                End If

                Dim UrlShrinkRequest As WebRequest = WebRequest.Create(strServiceUrl + Url)
                Dim UrlShrinkResponse As WebResponse = UrlShrinkRequest.GetResponse()

                Using reader As StreamReader = New StreamReader(UrlShrinkResponse.GetResponseStream())
                    Return reader.ReadToEnd()
                End Using

            Catch ex As Exception
                'If there was an exception, 
                'then just return the original url
                Return Url
            End Try

        End Function

As you can see from the “select case” you can pass it the service name (tinyurl, isgd, or zima), and it will shrink the URL using the appropriate service. You can also augment this function, of course, with any other service that exposes a RESTFUL API that takes a string as input (the original URL), and returns a string back (the shortened URL).

I will continue updating this function by adding additional services as time goes on. If you find any service that you think should make it to this list, please let me by posting a comment below.