DNN Community Blog

Do you have useful information that you would like to share with the DNN Community in a featured article or blog? If so, please contact community@dnnsoftware.com.

 


Caching in DNN 5

One of the hidden gems in DotNetNuke 5.0 is the new caching support in the CBO (Custom Business Objects) class. During the refactoring of DotNetNuke for the Cambrian release, caching was one of the things that was closely looked at, since caching was starting to cause major issues in the DNN 4.x branch.

Lets take a look at how caching was done in DNN 4:

        Public Shared Function GetSecureHostSettings() As Hashtable
            Dim h As Hashtable
            h = CType(DataCache.GetCache("GetSecureHostSettings"), Hashtable)
            If h Is Nothing Then
                h = New Hashtable
                Dim SettingName As String
                Dim dr As IDataReader = DataProvider.Instance().GetHostSettings
                While dr.Read()
                    If Not Convert.ToBoolean(dr(2)) Then
                        SettingName = dr.GetString(0)
                        If SettingName.ToLower.IndexOf("password") = -1 Then
                            If Not dr.IsDBNull(1) Then
                                h.Add(SettingName, dr.GetString(1))
                            Else
                                h.Add(SettingName, "")
                            End If
                        End If
                    End If
                End While
                dr.Close()
                DataCache.SetCache("GetSecureHostSettings", h)
            End If
            Return h
        End Function

 

This is code from the class DotNetNuke.Entities.Host.HostSettings in DNN 4.9.3. In fact this is a pattern that is used throughout the application in DNN 3.x – 4.x. The problem with this pattern is that it is not completely thread safe, especially if it is used in larger routines, and specifically on large and busy sites. There might be a chance that the object you get from the cache is removed from cache when you want to use it.

In DotNetNuke 5.x, the CBO class was beefed up with a new caching function:

        Public Shared Function GetCachedObject(Of TObject)(ByVal cacheItemArgs As CacheItemArgs, ByVal cacheItemExpired As CacheItemExpiredCallback) As TObject
            Return DataCache.GetCachedData(Of TObject)(cacheItemArgs, cacheItemExpired)
        End Function

which in turn calls a new method of DataCache, GetCachedData. This method looks like this:

        Public Shared Function GetCachedData(Of TObject)(ByVal cacheItemArgs As CacheItemArgs, ByVal cacheItemExpired As CacheItemExpiredCallback) As TObject
            'Declare Local Variable and try and retieve it from the cache
            Dim objObject As Object = GetCache(cacheItemArgs.CacheKey)
            Dim timeOut As Integer = cacheItemArgs.CacheTimeOut * Convert.ToInt32(Host.PerformanceSetting)

            'If Item is not cached
            If objObject Is Nothing Then

                'Prevent other threads from entering this block while we regenerate the cache
                SyncLock objLock

                    'Try to retrieve object from Cache again (in case another thread loaded the object since we first checked)
                    objObject = GetCache(cacheItemArgs.CacheKey)

                    If objObject Is Nothing Then
                        'Get Object from data Source using Delegate
                        objObject = cacheItemExpired(cacheItemArgs)

                        If objObject IsNot Nothing AndAlso timeOut > 0 Then
                            DataCache.SetCache(cacheItemArgs.CacheKey, objObject, cacheItemArgs.CacheDependency, Cache.NoAbsoluteExpiration, _
                                               TimeSpan.FromMinutes(timeOut), cacheItemArgs.CachePriority, cacheItemArgs.CacheCallback)

                            'Check if Item was actually saved in the cache
                            If DataCache.GetCache(cacheItemArgs.CacheKey) Is Nothing Then
                                Dim objEventLogInfo As New LogInfo
                                objEventLogInfo.LogTypeKey = EventLogController.EventLogType.CACHE_ERROR.ToString()
                                objEventLogInfo.LogProperties.Add(New LogDetailInfo(cacheItemArgs.CacheKey, "Not Created"))
                                Dim objEventLog As New EventLogController()
                                objEventLog.AddLog(objEventLogInfo)
                            End If
                        ElseIf objObject Is Nothing Then
                            Return Nothing
                        End If
                    End If
                End SyncLock
            End If

            Return DirectCast(objObject, TObject)
        End Function
 

As you can see, this is basically still the same pattern as the “old” pattern in DNN 3.x/4.x, however, with a few enhancements:

  • Thread safety. Using Synlock, other threads are prevented to intrude when we are handling the object
  • automatic callback is used, that will get called when the object is not found in cache
  • check to ensure object was saved to cache correctly

 

As an example of the usage of the new pattern, let’s see how Host.GetSecureHostSettings was modified in DNN 5:

        Public Shared Function GetSecureHostSettingsDictionary() As Dictionary(Of String, String)
            Return CBO.GetCachedObject(Of Dictionary(Of String, String))(New CacheItemArgs(DataCache.SecureHostSettingsCacheKey, _
                                                                                               DataCache.HostSettingsCacheTimeOut, _
                                                                                               DataCache.HostSettingsCachePriority), _
                                                                                               AddressOf GetSecureHostSettingsDictionaryCallBack)
        End Function

And the corresponding callback function:

        Private Shared Function GetSecureHostSettingsDictionaryCallBack(ByVal cacheItemArgs As CacheItemArgs) As Object
            Dim dicSettings As New Dictionary(Of String, String)

            Dim dr As IDataReader = DataProvider.Instance().GetHostSettings
            Try
                While dr.Read()
                    If Not Convert.ToBoolean(dr(2)) Then
                        Dim settingName As String = dr.GetString(0)
                        If settingName.ToLower.IndexOf("password") = -1 Then
                            If Not dr.IsDBNull(1) Then
                                dicSettings.Add(settingName, dr.GetString(1))
                            Else
                                dicSettings.Add(settingName, "")
                            End If
                        End If
                    End If
                End While
            Finally
                If Not dr Is Nothing Then
                    dr.Close()
                End If
            End Try

            Return dicSettings
        End Function

 

As you can see, the callback function GetSecureHostSettingsDictionaryCallBack is essentially the same as the old method, minus the caching logic. It has become far more easier to use caching in your own module using this pattern. A few lines of code will do the trick.

Comments

Comment Form

Only registered users may post comments.

NewsArchives


July 2014 (15)
June 2014 (10)
May 2014 (6)
April 2014 (9)
March 2014 (3)
February 2014 (4)
January 2014 (8)
December 2013 (5)
November 2013 (2)
October 2013 (9)
September 2013 (10)
August 2013 (8)
July 2013 (4)
June 2013 (8)
May 2013 (13)
April 2013 (2)
March 2013 (7)
February 2013 (7)
January 2013 (10)
December 2012 (6)
November 2012 (20)
October 2012 (12)
September 2012 (27)
August 2012 (29)
July 2012 (22)
June 2012 (17)
May 2012 (23)
April 2012 (24)
March 2012 (27)
February 2012 (21)
January 2012 (12)
December 2011 (18)
November 2011 (20)
October 2011 (27)
September 2011 (17)
August 2011 (18)
July 2011 (45)
June 2011 (22)
May 2011 (23)
April 2011 (19)
March 2011 (36)
February 2011 (19)
January 2011 (22)
December 2010 (29)
November 2010 (37)
October 2010 (32)
September 2010 (43)
August 2010 (46)
July 2010 (37)
June 2010 (46)
May 2010 (29)
April 2010 (38)
March 2010 (27)
February 2010 (33)
January 2010 (34)
December 2009 (13)
November 2009 (20)
October 2009 (29)
September 2009 (18)
August 2009 (29)
July 2009 (19)
June 2009 (18)
May 2009 (23)
April 2009 (16)
March 2009 (13)
February 2009 (20)
January 2009 (25)
December 2008 (25)
November 2008 (29)
October 2008 (34)
September 2008 (33)
August 2008 (36)
July 2008 (31)
June 2008 (25)
May 2008 (26)
April 2008 (33)
March 2008 (31)
February 2008 (24)
January 2008 (18)
December 2007 (27)
November 2007 (51)
October 2007 (24)
September 2007 (32)
August 2007 (24)
July 2007 (20)
June 2007 (28)
May 2007 (27)
April 2007 (24)
March 2007 (47)
February 2007 (21)
January 2007 (41)
December 2006 (21)
November 2006 (16)
October 2006 (24)
September 2006 (36)
August 2006 (30)
July 2006 (31)
June 2006 (37)
May 2006 (13)
April 2006 (13)
March 2006 (18)
February 2006 (20)
January 2006 (13)
December 2005 (6)
November 2005 (15)
October 2005 (15)
September 2005 (16)
August 2005 (7)
April 2005 (1)
March 2004 (4)
February 2004 (6)
January 2004 (1)
November 2003 (4)
October 2003 (22)
September 2003 (22)
August 2003 (15)
July 2003 (14)

Copyright 2014 by DNN Corp | Terms of Use | Privacy | Design by Parker Moore Design